|
沙发
发表于 2024-6-9 13:20:02
|
只看该作者
IP:山东
可以先打开游戏平台再打开启动器也可以试试这个小工具
@echo off
title 一键启动游戏平台和启动器
setlocal enabledelayedexpansion
for /f "usebackq tokens=2*" %%A in (`reg query "HKCU\Software\Netease\MCLauncher" /v "InstallLocation"`) do (
set "WPFL=%%B"
)
REM 检查游戏平台是否正在运行
tasklist | find /i "FeverGamesInstaller.exe" >nul
set FeverGamesRunning=!errorlevel!
REM 检查启动器是否正在运行
tasklist | find /i "WPFLauncher.exe" >nul
set LauncherRunning=!errorlevel!
REM 如果游戏平台和启动器都已经运行,则不执行任何操作并结束脚本
if !FeverGamesRunning! equ 0 if !LauncherRunning! equ 0 goto tiaozhuan
REM 如果游戏平台正在运行而启动器没有运行,则打开启动器然后关闭游戏平台
if !FeverGamesRunning! equ 0 (
echo.
echo 发烧游戏平台正在运行中
if !LauncherRunning! equ 1 (
echo.
echo 打开我的世界启动器,然后关闭游戏平台。
start "" "%WPFL%\WPFLauncher.exe"
echo 请稍后……
REM 如果启动器登录失败提示:请前往发烧游戏平台启动游戏,请将 /t 10 中的时间延长
timeout /t 10 /nobreak>nul
tasklist | find /i "WPFLauncher.exe" >nul
if !errorlevel! equ 0 (
echo.
echo 关闭发烧游戏平台
taskkill /im "FeverGamesInstaller.exe" /f
)
)
)
REM 如果启动器正在运行而游戏平台没有运行,则打开游戏平台
if !LauncherRunning! equ 0 (
echo.
echo 我的世界启动器正在运行中
if !FeverGamesRunning! equ 1 (
echo.
echo 打开发烧游戏平台
start "" "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\网易发烧游戏.lnk"
)
)
REM 如果游戏平台和启动器都没有运行,则先打开游戏平台,再打开启动器
REM 然后检测启动器进程是否打开,如果打开则10秒后关闭游戏平台
if !FeverGamesRunning! equ 1 (
if !LauncherRunning! equ 1 (
echo.
echo 正在打开发烧游戏平台
start "" "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\网易发烧游戏.lnk"
echo.
echo 正在打开我的世界启动器
start "" "%WPFL%\WPFLauncher.exe"
echo 请稍后……
REM 如果启动器登录失败提示:请前往发烧游戏平台启动游戏,请将 /t 10 中的时间延长
timeout /t 10 /nobreak>nul
tasklist | find /i "WPFLauncher.exe" >nul
if !errorlevel! equ 0 (
echo.
echo 关闭发烧游戏平台
taskkill /im "FeverGamesInstaller.exe" /f
)
)
)
:GB
echo.
echo 命令执行完毕。
timeout /t 5 /nobreak>nul
echo.
echo 自动关闭窗口
timeout /t 1 /nobreak>nul
exit /b
:tiaozhuan
echo.
echo 游戏发烧平台 正在运行中
timeout /t 1 /nobreak>nul
echo.
echo 我的世界启动器 正在运行中
goto GB
复制代码粘贴到记事本然后选择另存为,编码改成 ANSI 文件后缀名改成 .cmd 或 .bat 保存后双击运行看是否能启动启动器
|
|
|
因为论坛原因我只能用自动插件添加了这个伪签名档,与回复主题无关
|
|